result of combination ( few numbers)

[CRGreathouse]

Originally Posted by a1call

Not most efficient code but it should work.

theCounter = 19
theOldString = ""
forstep(i1=1,9,2,{
  forstep(i2=1,9,2,
    forstep(i3=1,9,2,
      forstep(i4=1,9,2,
        forstep(i5=1,9,2,
          theString = Str(i1,i2,i3,i4,i5) ;
          if (theOldString != theString ,
            theOldString = theString;
            print(theString );
          );
          theCounter = theCounter -1;
          if (theCounter <1, next(19););
        );
      );
    );
  );
})

You can do

forvec(v=vector(4,i,[1,5]), print(fromdigits(apply(n->2*n-1, v))))

where forvec does the work of the five loops, apply converts 1..5 to 1,3,5,7,9, and fromdigits converts [1,3,5,7] to 1357. (The base is 10 unless you give a different base as a second argument.)

[a1call]

I have never been able to make forvec work before. I find the documentation vague without any examples. I will come back to your example next time I need it.
Apply and fromdigits is news to me.
For 0,1,3,5,7,9 , wouldn't it be easier to include them in the vector rather than formulate a conversion?
Thank you for code.

[CRGreathouse]

Originally Posted by a1call

I have never been able to make forvec work before. I find the documentation vague without any examples.

Yes, the forvec documentation is bad.

The basic idea is that you can replace a collection of nested for loops like this:

for(i1=start1,end1,
  for(i2=start2,end2,
    ...
      [i1, i2, ...]
    ...
  )
)

with

forvec(v=[ [start1,end1], [start2,end2], ...],
  v
)

There is an optional final argument that if set to 1 gives only weakly increasing vectors ([1, 1, 2] but not [2, 1, 2]), and if set to 2 gives only strictly increasing vectors ([1, 2, 3] but not [1, 2, 2]). So you can replace

for(a=0,6, for(b=a+1,7, for(c=b+1,8, for(d=c+1,9, f(a,b,c,d)))))

with

forvec(v=vector(4,i,[0,9]), f(v[1],v[2],v[3],v[4]), 2)

which can be abbreviated

forvec(v=vector(4,i,[0,9]), call(f,v), 2)

Originally Posted by a1call

For 0,1,3,5,7,9 , wouldn't it be easier to include them in the vector rather than formulate a conversion?

For me it would be easier and more natural to use a vector rather than gluing them together as a decimal number, but I wanted to match your output.

Originally Posted by a1call

Apply and fromdigits is news to me.

fromdigits is boring -- fromdigits([1, 2, 3]) is 123 and fromdigits([1, 0, 1], 2) is 5 (binary).

apply is great, I use it all the time. apply(f, [1, 2, 3]) returns [f(1), f(2), f(3)], where f is some function. (Of course the function is computed, it doesn't actually write "f(1)" unless that's what the function does.) apply(cos, [0, Pi/2, Pi]) gives approximately [1, 0, -1].

In my example I used a 'lambda' type expression to define an anonymous function. Instead I could have written

doubleMinusOne(n)=2*n-1;
forvec(v=vector(4,i,[1,5]), print(fromdigits(apply(doubleMinusOne, v))))

but this way I don't have to think up a name for this little function that I'm only using in this one spot.

[CRGreathouse]

Originally Posted by CRGreathouse

Yes, the forvec documentation is bad.

Also, I think scienceman88 uses forvec a lot, he might have more useful examples if mine don't help.

[a1call]

Thank you for the very detailed explanation CRG. Much appreciated.

[science_man_88]

Originally Posted by CRGreathouse

Also, I think scienceman88 uses forvec a lot, he might have more useful examples if mine don't help.

I actually don't even use fold as much as I should I did implement Jordan's totient function at one point ( see my pastebin).