Just dreamed this one up....

[petrw1]

What is the largest prime number you can find such that all groupings of numbers in order are also prime....
For example in the prime 373 all the following in () are also prime
(3)73, 3(7)3, 37(3), (37)3, 3(73)

Obviously it can only contain the digits 2, 3, 5, 7

I believe the first 5 non-trivial are:
23, 37, 53, 73, 373,

[axn]

Originally Posted by petrw1

I believe the first 5 non-trivial are:
23, 37, 53, 73, 373,

And those are the only solutions :-(

To create an n-digit solution, you need an n-1 digit solution and extend it by prefixing or suffixing another digit.
2 and 5 can only go as leading digit.
Same digit cannot occur consecutively.

With these restrictions, we see that the four 2-digit solutions and the one 3-digit solution are the only ones possible. 373 is a dead end. It cannot be extended further.

[petrw1]

...

[Antonio]

I offer 1373

(Ok, so I know 1 isn't strictly prime, but then it's not composite so there are no composites in any of the groupings.)

[legendarymudkip]

Originally Posted by Antonio

I offer 1373

(1)373 - 1 is not prime.

[Antonio]

Originally Posted by legendarymudkip

(1)373 - 1 is not prime.

Oops, replied while I was editing in the last sentence.

[LaurV]

Actually, let's allow 1 into it, to make it a bit more.. attractive. This way, you can have a 1 here and there, and even two of 1, as 11, 13, 17, 31, 71, are all prime... How high can you go?

[petrw1]

3137

your turn...hint no more of 4-digits

[LaurV]

Ha! I made you lose 20 minutes from your DC time! Every time you lose is a gain for me, so I can overtake you in the DC top..

Joking apart (not!), I was too lazy/stupid to think (and anyhow one needs a calculator/computer to check the primality of 4-digits and more numbers), so I decided to write a pari/gp script, which took me about the same amount of time.

Unfortunately I can't argue against you since my script says you are right... what a pity...
These are all the solutions:

gp > \r digits
%xx = List([1, 2, 3, 5, 7])
time = 4 ms.
%xx = List([1, 2, 3, 5, 7, 11, 13, 17, 23, 31, 37, 53, 71, 73, 113, 131, 137, 173, 311, 313, 317, 373, 1373, 3137])
gp >

Here is the script to which I spent some more time to beautify and print the intermediary steps, you can directly paste it into the pari screen (or save it in a separate file) if you want to play with it (i.e lose even more time apart from the DC tasks... :hehe:)

adg(digit=1, size=1)=
{
    my(cnt=0,k,n,t,isp,ls);
    
    for(i=1,#glist,
        n=glist[i];
        if(10^(size-1)<=n && n<10^size,
        
            /*add on the back*/
            k=1;
            isp=1;
            while(isp && k<=n,
                k*=10;
                if(!isprime((n%k)*10+digit),
                    isp=0
                )
            );
            
            if(isp,
                ls=#glist;
                listput(glist,n*10+digit);
                listsort(glist,1);
                if(ls!=#glist,
                    cnt++
                )
            );
            
            /* add on the front */
            k=ceil(log(n)/log(10));
            if(n==1,k=1);
            t=k;
            isp=1;
            while(isp && k>0,
                if(!isprime(digit*10^k+floor(n/10^(t-k))),
                    isp=0
                );
                k--
            );
            if(isp,
                ls=#glist;
                listput(glist,digit*10^t+n);
                listsort(glist,1);
                if(ls!=#glist,
                    cnt++
                )
            )
        )
    );
    cnt
};

adigi(maxsize=8)=
{
    my(s,ls);
    for(size=1,maxsize,
        until(s==0,
            s=0;
            forstep(i=1,7,2,
                ls=#glist;
                s=max(s,adg(i,size));
                if(ls!=#glist,
                    print(glist)
                )
            );
            ls=#glist;
            s=max(s,adg(2,size));
            if(ls!=#glist,
                print(glist)
            )
        )
    )
};

glist=List([1,2,3,5,7])
adigi()
glist